***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Aug 09, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PZS516V2BCH A K
.param
+vc0 = 7.741e-12	 vc1 = 7.853e-12	 vc2 = 2.254		 vc3 = 7.651e-13		 vc4 = 2.685
+tc1 = 1.351e-2		 tc2 = 2.831e-2		 tc3 = 5.941e-3		 tc4 = 5.021e-3	
.func irexp(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter ***
+level = 1   
***** dc model parameter ***
+ is = 5.240e-16	   n = 9.983e-1		  rs = 9.595e-2		 ikf = 3.869e-1
+ibv = 50e-6		 nbv = 1		  bv = 6.2
***** capacitance parameter ***
+cjo = 1.759e-10	   m = 3.264e-1		  vj = 6.496e-1
+ fc = 0.5                      
***** temperature coefficient ***
+tnom = 25		  eg = 1.108		 xti = 3
+trs1 = -6.742e-4	tbv1 = 3.470e-4		tbv2 = 5.505e-8		tikf = 3.512e-3
.ends PZS516V2BCH
*$
